單片機實驗開發(fā)板測試程序詳解
通常我們網(wǎng)站提供的試驗開發(fā)板是焊接并測試好的成品板，如果是購買套件的網(wǎng)友，可以開始51單片機實驗板的一系列安裝與實驗，網(wǎng)友郵購的實驗板套件包含以下的元件清單，收到貨物后請仔細核對一下元件清單：
AT89C51單片機實驗開發(fā)板套件元件清單：
專門設(shè)計的全工藝電路板一塊
電源部分元件：
1． 9伏左右直流插頭式小電源，帶插頭(空載12伏)
2． 電源插座一個
3． 7805穩(wěn)壓芯片一個
4． 470UF/16V電源濾波電容兩個
5． 0.1UF獨石電容兩個
6． 電源指示綠色LED一個
7． LED限流電阻560歐姆電阻一個
單片機必須部分的元件：
1． AT89C51單片機芯片一片
2． 40腳零拔插力ZIF插座一個
3． 復位用電容22UF/16V電容一個
4． 復位用電阻1K一個
5． 30P小電容2個
6． 12M晶振一個
實驗部分元件：
1． 8個小紅色長方形LED
2． 8位1K數(shù)碼管限流排阻
3． 1個共陰兩位一體化的數(shù)碼管一個
4． 一個5伏電磁型蜂鳴器
5． 1個8550驅(qū)動三極管（e/b/c)
6． 3個1K三極管基極驅(qū)動電阻
7． 微型輕觸開關(guān)4個
8． 4位的紅色撥碼開關(guān)一個
9． 2個12伏JQC-3F繼電器（一組常開轉(zhuǎn)常閉）
10．2個IN4148防反峰二極管
11. 2個8050驅(qū)動三極管(e/b/c)
12. 2個繼電器狀態(tài)指示紅色發(fā)光二極管
1． 原裝進口MAX232芯片一片
2． 5.1K上拉電阻兩個
3． 10UF電容4個
4． 塑封一體化紅外線接收頭一個
5． AT24C02存儲器芯片一片
6． 220UF濾波電容一個
7． 0.1UF電容一個
8． 32個按鍵的紅外遙控手柄一個
9． 串口通訊電纜一根
10. DS18B20的4.7K上拉電阻一個
對于購買成品板的網(wǎng)友拿到的是經(jīng)過焊接好的產(chǎn)品，并且經(jīng)過測試完好，不管是購買套件還是成品單片機實驗開發(fā)板的網(wǎng)友得到的單片機中都已經(jīng)燒錄了一個測試程序，測試程序主要是用來測試51試驗板的單片機和相關(guān)外圍元件的好壞，如果這個程序能夠順利運行，說明實驗板的各方面都很正常。
測試程序?qū)τ诔鯇W者來說可能比較復雜,但是也是由網(wǎng)站上幾個小程序組合而成的，初學者可以通過后面教程的學習來掌握這段程序。
這個測試程序的功能是：接通電源后P0口的八個發(fā)光二極管依次從下往上點亮，然后蜂鳴器鳴叫一聲，兩個繼電器輪流動作一次，數(shù)碼管的個位顯示8，再換成十位顯示8，然后不斷循環(huán)，如果這時按下紅外遙控器的按鍵時，蜂鳴器立即發(fā)出“滴滴滴”的提示音，同時將這個按鍵的鍵值通過串口在電腦屏幕上顯示出來（需要運行串口調(diào)試軟件）通過這個程序可以判斷單片機實驗開發(fā)板的各個部分的硬件和軟件都是完好的，具體的源程序如下：
ORG 0000H
AJMP MAIN;轉(zhuǎn)入主程序
ORG 0003H;外部中斷P3.2腳INT0入口地址
AJMP INT;轉(zhuǎn)入外部中斷服務(wù)子程序（紅外遙控解碼程序）
;以下為主程序進行CPU中斷方式設(shè)置
MAIN:LCALL YS3;等待硬件上電穩(wěn)定
SETB EA;打開CPU總中斷請求
SETB IT0;設(shè)定INT0的觸發(fā)方式為脈沖負邊沿觸發(fā)
SETB EX0;打開INT0中斷請求
MOV SCON,#50H;設(shè)置成串口1方式
MOV TMOD,#20H;波特率發(fā)生器T1工作在模式2上
MOV PCON,#80H;波特率翻倍為2400x2=4800BPS
MOV TH1,#0F3H;預(yù)置初值(按照波特率2400BPS預(yù)置初值)
MOV TL1,#0F3H;預(yù)置初值(按照波特率2400BPS預(yù)置初值)
SETB TR1;啟動定時器T1
;以上完成串口通訊初始化設(shè)置
START:MOV P1,#01111111B
LCALL DELAY
MOV P1,#10111111B
LCALL DELAY
MOV P1,#11011111B
LCALL DELAY
MOV P1,#11101111B
LCALL DELAY
MOV P1,#11110111B
LCALL DELAY
MOV P1,#11111011B
LCALL DELAY
MOV P1,#11111101B
LCALL DELAY
MOV P1,#11111110B;P1口的LED循環(huán)由下往上點亮一次,延時約250毫秒
LCALL DELAY
MOV P2,#11011111B;蜂鳴器鳴響一聲
LCALL DELAY
MOV P2,#11101111B;繼電器J1吸合一次
LCALL DELAY
MOV P2,#11110111B;繼電器J2吸合一次
LCALL DELAY
MOV P0,#0FFH
MOV P2,#01111111B;數(shù)碼管個位顯示8
LCALL DELAY
MOV P0,#0FFH
MOV P2,#10111111B;數(shù)碼管十位顯示8
LCALL DELAY
AJMP START;反復循環(huán)
;以下為進入P3.2腳外部中斷子程序，也就是解碼程序
INT: CLR EA;暫時關(guān)閉CPU的所有中斷請求
MOV R6,#10
SB: ACALL YS1;調(diào)用882微秒延時子程序
JB P3.2,EXIT;延時882微秒后判斷P3.2腳是否出現(xiàn)高電平如果有就退出解碼程序
DJNZ R6, SB;重復10次，目的是檢測在8820微秒內(nèi)如果出現(xiàn)高電平就退出解碼程序
;以上完成對遙控信號的9000微秒的初始低電平信號的識別。
JNB P3.2, $;等待高電平避開9毫秒低電平引導脈沖
ACALL YS2;延時4.74毫秒避開4.5毫秒的結(jié)果碼
MOV R7,#26;忽略前26位系統(tǒng)識別碼
JJJJA:JNB P3.2,$;等待地址碼第一位的高電平信號
LCALL YS1;高電平開始后用882微秒的時間尺去判斷信號此時的高低電平狀態(tài)
MOV C,P3.2;將P3.2引腳此時的電平狀態(tài)0或1存入C中
JNC UUUA;如果為0就跳轉(zhuǎn)到UUUA
LCALL YS3;檢測到高電平1的話延時1毫秒等待脈沖高電平結(jié)束
UUUA: DJNZ R7,JJJJA
MOV R1,#1AH ;設(shè)定1AH為起始RAM區(qū)
MOV R2,#2;接收從1AH到1BH的2個內(nèi)存,用于存放操作碼和操作反碼
PP: MOV R3,#8;每組數(shù)據(jù)為8位
JJJJ: JNB P3.2,$;等待地址碼第一位的高電平信號
LCALL YS1;高電平開始后用882微秒的時間尺去判斷信號此時的高低電平狀態(tài)
MOV C,P3.2;將P3.2引腳此時的電平狀態(tài)0或1存入C中
JNC UUU;如果為0就跳轉(zhuǎn)到UUU
LCALL YS3;檢測到高電平1的話延時1毫秒等待脈沖高電平結(jié)束
UUU: MOV A,@R1;將R1中地址的給A
RRC A;將C中的值0或1移入A中的最低位
MOV @R1,A;將A中的數(shù)暫時存放在R1數(shù)值的內(nèi)存中
DJNZ R3,JJJJ;接收滿8位換一個內(nèi)存
INC R1;對R1中的值加1，換下一個RAM
DJNZ R2,PP ;接收完8位數(shù)據(jù)碼和8位數(shù)據(jù)反碼，存放在1AH/1BH中
MOV A,1AH
CPL A;對1AH取反后和1BH比較
CJNE A,1BH,EXIT;如果不等表示接收數(shù)據(jù)發(fā)生錯誤,放棄
MOV P1,1AH;將按鍵的鍵值通過P1口的8個LED顯示出來!
MOV A,1AH;將紅外遙控器具體按鍵的鍵值發(fā)送到串口去
MOV SBUF,A;通過串口在電腦屏幕上顯示出來
CLR P2.5;蜂鳴器鳴響嘀嘀嘀的聲音，表示解碼成功
LCALL YS2
LCALL YS2
LCALL YS2
SETB P2.5;蜂鳴器停止
EXIT: SETB EA ;允許中斷
RETI ;退出解碼子程序
YS1: MOV R4,#20 ;（占用R4/R5）延時子程序1，精確延時882微秒
D1: MOV R5,#20
DJNZ R5,$
DJNZ R4,D1
RET
YS2: MOV R4,#10 ;（占用R4/R5）延時子程序2，精確延時4740微秒
D2: MOV R5,#235
DJNZ R5,$
DJNZ R4,D2
RET
YS3: MOV R4,#2;（占用R4/R5）延時程序3，精確延時1000微秒
D3:MOV R5,#248
DJNZ R5,$
DJNZ R4,D3
RET
DELAY:MOV R1,#08H;（占用R1/R2/R3）延時子程序，12M晶振延時約250毫秒
L3: MOV R2 ,#0FAH
L1: MOV R3 ,#0FAH
L2: DJNZ R3 ,L2
DJNZ R2 ,L1
DJNZ R1 ,L3
RET
END
下一篇文章：單片機電源安裝調(diào)試
備注：如果不需要AT89C51實驗開發(fā)板中的12伏電源變壓器，價格可以降低10元
郵局匯款地址：郵編226200 江蘇省啟東市江海中路511號水晶苑 A－1 謝剛 收
電話/傳真：0513－83342087 小靈通：0513－83082087 聯(lián)系人：謝剛
電子信箱：