DS18B20智能溫度控制器
DS18B20智能溫度控制器
DALLAS最新單線數(shù)字溫度傳感器DS18B20簡介新的“一線器件”體積更小、適用電壓更寬、更經(jīng)濟(jì) Dallas 半導(dǎo)體公司的數(shù)字化溫度傳感器DS1820是世界上第一片支持 “一線總線”接口的溫度傳感器。一線總線獨(dú)特而且經(jīng)濟(jì)的特點(diǎn)，使用戶可輕松地組建傳感器網(wǎng)絡(luò)，為測量系統(tǒng)的構(gòu)建引入全新概念。DS18B20、 DS1822 “一線總線”數(shù)字化溫度傳感器 同DS1820一樣，DS18B20也 支持“一線總線”接口，測量溫度范圍為 -55°C~+125°C，在-10~+85°C范圍內(nèi),精度為±0.5°C。DS1822的精度較差為± 2°C �，F(xiàn)場溫度直接以“一線總線”的數(shù)字方式傳輸，大大提高了系統(tǒng)的抗干擾性。適合于惡劣環(huán)境的現(xiàn)場溫度測量，如：環(huán)境控制、設(shè)備或過程控制、測溫類消費(fèi)電子產(chǎn)品等。與前一代產(chǎn)品不同，新的產(chǎn)品支持3V~5.5V的電壓范圍，使系統(tǒng)設(shè)計(jì)更靈活、方便。而且新一代產(chǎn)品更便宜，體積更小。 DS18B20、 DS1822 的特性 DS18B20可以程序設(shè)定9~12位的分辨率，精度為±0.5°C�？蛇x更小的封裝方式，更寬的電壓適用范圍。分辨率設(shè)定，及用戶設(shè)定的報(bào)警溫度存儲在EEPROM中，掉電后依然保存。DS18B20的性能是新一代產(chǎn)品中最好的！性能價(jià)格比也非常出色！ DS1822與 DS18B20軟件兼容，是DS18B20的簡化版本。省略了存儲用戶定義報(bào)警溫度、分辨率參數(shù)的EEPROM，精度降低為±2°C，適用于對性能要求不高，成本控制嚴(yán)格的應(yīng)用，是經(jīng)濟(jì)型產(chǎn)品。 繼“一線總線”的早期產(chǎn)品后，DS1820開辟了溫度傳感器技術(shù)的新概念。DS18B20和DS1822使電壓、特性及封裝有更多的選擇，讓我們可以構(gòu)建適合自己的經(jīng)濟(jì)的測溫系統(tǒng)。
DS18B20的內(nèi)部結(jié)構(gòu)
DS18B20內(nèi)部結(jié)構(gòu)主要由四部分組成：64位光刻ROM、溫度傳感器、非揮發(fā)的溫度報(bào)警觸發(fā)器TH和TL、配置寄存器。DS18B20的管腳排列如下:
DQ為數(shù)字信號輸入/輸出端；GND為電源地；VDD為外接供電電源輸入端（在寄生電源接線方式時接地）。
光刻ROM中的64位序列號是出廠前被光刻好的，它可以看作是該DS18B20的地址序列碼。64位光刻ROM的排列是：開始8位（28H）是產(chǎn)品類型標(biāo)號，接著的48位是該DS18B20自身的序列號，最后8位是前面56位的循環(huán)冗余校驗(yàn)碼（CRC=X8+X5+X4+1）。光刻ROM的作用是使每一個DS18B20都各不相同，這樣就可以實(shí)現(xiàn)一根總線上掛接多個DS18B20的目的。
DS18B20中的溫度傳感器可完成對溫度的測量，以12位轉(zhuǎn)化為例:用16位符號擴(kuò)展的二進(jìn)制補(bǔ)碼讀數(shù)形式提供，以0.0625℃/LSB形式表達(dá)，其中S為符號位。
這是12位轉(zhuǎn)化后得到的12位數(shù)據(jù)，存儲在18B20的兩個8比特的RAM中，二進(jìn)制中的前面5位是符號位，如果測得的溫度大于0，這5位為0，只要將測到的數(shù)值乘于0.0625即可得到實(shí)際溫度；如果溫度小于0，這5位為1，測到的數(shù)值需要取反加1再乘于0.0625即可得到實(shí)際溫度。
例如+125℃的數(shù)字輸出為07D0H，+25.0625℃的數(shù)字輸出為0191H，-25.0625℃的數(shù)字輸出為FF6FH，-55℃的數(shù)字輸出為FC90H。
DS18B20溫度傳感器的存儲器
DS18B20溫度傳感器的內(nèi)部存儲器包括一個高速暫存RAM和一個非易失性的可電擦除的E2RAM,后者存放高溫度和低溫度觸發(fā)器TH、TL和結(jié)構(gòu)寄存器。
暫存存儲器包含了8個連續(xù)字節(jié)，前兩個字節(jié)是測得的溫度信息，第一個字節(jié)的內(nèi)容是溫度的低八位，第二個字節(jié)是溫度的高八位。第三個和第四個字節(jié)是TH、TL的易失性拷貝，第五個字節(jié)是結(jié)構(gòu)寄存器的易失性拷貝，這三個字節(jié)的內(nèi)容在每一次上電復(fù)位時被刷新。第六、七、八個字節(jié)用于內(nèi)部計(jì)算。第九個字節(jié)是冗余檢驗(yàn)字節(jié)。
該字節(jié)各位的意義如下：
TM R1 R0 1 1 1 1 1
低五位一直都是1 ，TM是測試模式位，用于設(shè)置DS18B20在工作模式還是在測試模式。在DS18B20出廠時該位被設(shè)置為0，用戶不要去改動。R1和R0用來設(shè)置分辨率，如下表所示：（DS18B20出廠時被設(shè)置為12位）
分辨率設(shè)置表:
R1 |
R0 |
分辨率 |
溫度最大轉(zhuǎn)換時間 |
0 |
0 |
9位 |
93.75ms |
0 |
1 |
10位 |
187.5ms |
1 |
0 |
11位 |
375ms |
1 |
1 |
12位 |
750ms |
根據(jù)DS18B20的通訊協(xié)議，主機(jī)控制DS18B20完成溫度轉(zhuǎn)換必須經(jīng)過三個步驟：每一次讀寫之前都要對DS18B20進(jìn)行復(fù)位，復(fù)位成功后發(fā)送一條ROM指令，最后發(fā)送RAM指令，這樣才能對DS18B20進(jìn)行預(yù)定的操作。復(fù)位要求主CPU將數(shù)據(jù)線下拉500微秒，然后釋放，DS18B20收到信號后等待16～60微秒左右，后發(fā)出60～240微秒的存在低脈沖，主CPU收到此信號表示復(fù)位成功。
DS1820使用中注意事項(xiàng)
DS1820雖然具有測溫系統(tǒng)簡單、測溫精度高、連接方便、占用口線少等優(yōu)點(diǎn)，但在實(shí)際應(yīng)用中也應(yīng)注意以下幾方面的問題：
(1)較小的硬件開銷需要相對復(fù)雜的軟件進(jìn)行補(bǔ)償，由于DS1820與微處理器間采用串行數(shù)據(jù)傳送，因此，在對DS1820進(jìn)行讀寫編程時，必須嚴(yán)格的保證讀寫時序，否則將無法讀取測溫結(jié)果。在使用PL/M、C等高級語言進(jìn)行系統(tǒng)程序設(shè)計(jì)時，對DS1820操作部分最好采用匯編語言實(shí)現(xiàn)。
(2)在DS1820的有關(guān)資料中均未提及單總線上所掛DS1820數(shù)量問題，容易使人誤認(rèn)為可以掛任意多個DS1820，在實(shí)際應(yīng)用中并非如此。當(dāng)單總線上所掛DS1820超過8個時，就需要解決微處理器的總線驅(qū)動問題，這一點(diǎn)在進(jìn)行多點(diǎn)測溫系統(tǒng)設(shè)計(jì)時要加以注意。
(3)連接DS1820的總線電纜是有長度限制的。試驗(yàn)中，當(dāng)采用普通信號電纜傳輸長度超過50m時，讀取的測溫?cái)?shù)據(jù)將發(fā)生錯誤。當(dāng)將總線電纜改為雙絞線帶屏蔽電纜時，正常通訊距離可達(dá)150m，當(dāng)采用每米絞合次數(shù)更多的雙絞線帶屏蔽電纜時，正常通訊距離進(jìn)一步加長。這種情況主要是由總線分布電容使信號波形產(chǎn)生畸變造成的。因此，在用DS1820進(jìn)行長距離測溫系統(tǒng)設(shè)計(jì)時要充分考慮總線分布電容和阻抗匹配問題。
(4)在DS1820測溫程序設(shè)計(jì)中，向DS1820發(fā)出溫度轉(zhuǎn)換命令后，程序總要等待DS1820的返回信號，一旦某個DS1820接觸不好或斷線，當(dāng)程序讀該DS1820時，將沒有返回信號，程序進(jìn)入死循環(huán)。這一點(diǎn)在進(jìn)行DS1820硬件連接和軟件設(shè)計(jì)時也要給予一定的重視。
測溫電纜線建議采用屏蔽4芯雙絞線，其中一對線接地線與信號線，另一組接VCC和地線，屏蔽層在源端單點(diǎn)接地。
點(diǎn)擊這里可以下載到DS18B20的原廠英文資料
這是我們用網(wǎng)站提供的AT89C51實(shí)驗(yàn)開發(fā)板做的溫度測量試驗(yàn)，DS18B20的正電源就是紅線接＋5伏，蘭線接地，棕色線接P2.2，（注意：四位撥碼開關(guān)的第3位不能處于ON的位置，否則實(shí)驗(yàn)無法成功�。�+5V和信號線之間有一個4.7K的上拉電阻，硬件就這么簡單，網(wǎng)友可以加15元向我郵購DS18B20測溫電纜，可以直接插在實(shí)驗(yàn)板上，就能使用。
軟件如下：
;這是關(guān)于DS18B20的讀寫程序,數(shù)據(jù)腳P2.2,晶振12MHZ
;溫度傳感器18B20匯編程序,采用器件默認(rèn)的12位轉(zhuǎn)化,最大轉(zhuǎn)化時間750微秒
;可以將檢測到的溫度直接顯示到AT89C51開發(fā)實(shí)驗(yàn)板的兩個數(shù)碼管上
;顯示溫度00到99度,很準(zhǔn)確哦~~無需校正!
ORG 0000H
;單片機(jī)內(nèi)存分配申明!
TEMPER_L EQU 29H;用于保存讀出溫度的低8位
TEMPER_H EQU 28H;用于保存讀出溫度的高8位
FLAG1 EQU 38H;是否檢測到DS18B20標(biāo)志位
a_bit equ 20h ;數(shù)碼管個位數(shù)存放內(nèi)存位置
b_bit equ 21h ;數(shù)碼管十位數(shù)存放內(nèi)存位置
MAIN:
LCALL GET_TEMPER;調(diào)用讀溫度子程序
;進(jìn)行溫度顯示,這里我們考慮用網(wǎng)站提供的兩位數(shù)碼管來顯示溫度
;顯示范圍00到99度,顯示精度為1度
;因?yàn)?2位轉(zhuǎn)化時每一位的精度為0.0625度,我們不要求顯示小數(shù)所以可以拋棄29H的低4位
;將28H中的低4位移入29H中的高4位,這樣獲得一個新字節(jié),這個字節(jié)就是實(shí)際測量獲得的溫度
;這個轉(zhuǎn)化溫度的方法可是我想出來的哦~~非常簡潔無需乘于0.0625系數(shù)
MOV A,29H
MOV C,40H;將28H中的最低位移入C
RRC A
MOV C,41H
RRC A
MOV C,42H
RRC A
MOV C,43H
RRC A
MOV 29H,A
LCALL DISPLAY;調(diào)用數(shù)碼管顯示子程序
CPL P1.0
AJMP MAIN
; 這是DS18B20復(fù)位初始化子程序
INIT_1820:
SETB P2.2
NOP
CLR P2.2
;主機(jī)發(fā)出延時537微秒的復(fù)位低脈沖
MOV R1,#3
TSR1:MOV R0,#107
DJNZ R0,$
DJNZ R1,TSR1
SETB P2.2;然后拉高數(shù)據(jù)線
NOP
NOP
NOP
MOV R0,#25H
TSR2:
JNB P2.2,TSR3;等待DS18B20回應(yīng)
DJNZ R0,TSR2
LJMP TSR4 ; 延時
TSR3:
SETB FLAG1 ; 置標(biāo)志位,表示DS1820存在
CLR P1.7;檢查到DS18B20就點(diǎn)亮P1.7LED
LJMP TSR5
TSR4:
CLR FLAG1 ; 清標(biāo)志位,表示DS1820不存在
CLR P1.1
LJMP TSR7
TSR5:
MOV R0,#117
TSR6:
DJNZ R0,TSR6 ; 時序要求延時一段時間
TSR7:
SETB P2.2
RET
; 讀出轉(zhuǎn)換后的溫度值
GET_TEMPER:
SETB P2.2
LCALL INIT_1820;先復(fù)位DS18B20
JB FLAG1,TSS2
CLR P1.2
RET ; 判斷DS1820是否存在?若DS18B20不存在則返回
TSS2:
CLR P1.3;DS18B20已經(jīng)被檢測到!!!!!!!!!!!!!!!!!!
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#44H ; 發(fā)出溫度轉(zhuǎn)換命令
LCALL WRITE_1820
;這里通過調(diào)用顯示子程序?qū)崿F(xiàn)延時一段時間,等待AD轉(zhuǎn)換結(jié)束,12位的話750微秒
LCALL DISPLAY
LCALL INIT_1820;準(zhǔn)備讀溫度前先復(fù)位
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#0BEH ; 發(fā)出讀溫度命令
LCALL WRITE_1820
LCALL READ_18200; 將讀出的溫度數(shù)據(jù)保存到35H/36H
CLR P1.4
RET
;寫DS18B20的子程序(有具體的時序要求)
WRITE_1820:
MOV R2,#8;一共8位數(shù)據(jù)
CLR C
WR1:
CLR P2.2
MOV R3,#6
DJNZ R3,$
RRC A
MOV P2.2,C
MOV R3,#23
DJNZ R3,$
SETB P2.2
NOP
DJNZ R2,WR1
SETB P2.2
RET
; 讀DS18B20的程序,從DS18B20中讀出兩個字節(jié)的溫度數(shù)據(jù)
READ_18200:
MOV R4,#2 ; 將溫度高位和低位從DS18B20中讀出
MOV R1,#29H ; 低位存入29H(TEMPER_L),高位存入28H(TEMPER_H)
RE00:
MOV R2,#8;數(shù)據(jù)一共有8位
RE01:
CLR C
SETB P2.2
NOP
NOP
CLR P2.2
NOP
NOP
NOP
SETB P2.2
MOV R3,#9
RE10:
DJNZ R3,RE10
MOV C,P2.2
MOV R3,#23
RE20:
DJNZ R3,RE20
RRC A
DJNZ R2,RE01
MOV @R1,A
DEC R1
DJNZ R4,RE00
RET
;顯示子程序
display: mov a,29H;將29H中的十六進(jìn)制數(shù)轉(zhuǎn)換成10進(jìn)制
mov b,#10 ;10進(jìn)制/10=10進(jìn)制
div ab
mov b_bit,a ;十位在a
mov a_bit,b ;個位在b
mov dptr,#numtab ;指定查表啟始地址
mov r0,#4
dpl1: mov r1,#250 ;顯示1000次
dplop: mov a,a_bit ;取個位數(shù)
MOVC A,@A+DPTR ;查個位數(shù)的7段代碼
mov p0,a ;送出個位的7段代碼
clr p2.7 ;開個位顯示
acall d1ms ;顯示1ms
setb p2.7
mov a,b_bit ;取十位數(shù)
MOVC A,@A+DPTR ;查十位數(shù)的7段代碼
mov p0,a ;送出十位的7段代碼
clr p2.6 ;開十位顯示
acall d1ms ;顯示1ms
setb p2.6
djnz r1,dplop ;100次沒完循環(huán)
djnz r0,dpl1 ;4個100次沒完循環(huán)
ret
;1MS延時(按12MHZ算)
D1MS: MOV R7,#80
DJNZ R7,$
RET
;實(shí)驗(yàn)板上的7段數(shù)碼管0～9數(shù)字的共陰顯示代碼
numtab: DB 0CFH,03H,5DH,5BH,93H,0DAH,0DEH,43H,0DFH,0DBH
end
點(diǎn)擊這里可以下載單片機(jī)實(shí)驗(yàn)開發(fā)板配套的程序。
;這是關(guān)于DS18B20的讀寫程序,數(shù)據(jù)腳P2.2,晶振11.0592mhz
;溫度傳感器18B20匯編程序,采用器件默認(rèn)的12位轉(zhuǎn)化,最大轉(zhuǎn)化時間750微秒
;可以將檢測到的溫度直接顯示到AT89C51開發(fā)實(shí)驗(yàn)板的兩個數(shù)碼管上
;顯示溫度00到99度,很準(zhǔn)確哦~~無需校正!
ORG 0000H
;單片機(jī)內(nèi)存分配申明!
TEMPER_L EQU 29H;用于保存讀出溫度的低8位
TEMPER_H EQU 28H;用于保存讀出溫度的高8位
FLAG1 EQU 38H;是否檢測到DS18B20標(biāo)志位
a_bit equ 20h ;數(shù)碼管個位數(shù)存放內(nèi)存位置
b_bit equ 21h ;數(shù)碼管十位數(shù)存放內(nèi)存位置
MAIN:
LCALL GET_TEMPER;調(diào)用讀溫度子程序
;進(jìn)行溫度顯示,這里我們考慮用網(wǎng)站提供的兩位數(shù)碼管來顯示溫度
;顯示范圍00到99度,顯示精度為1度
;因?yàn)?2位轉(zhuǎn)化時每一位的精度為0.0625度,我們不要求顯示小數(shù)所以可以拋棄29H的低4位
;將28H中的低4位移入29H中的高4位,這樣獲得一個新字節(jié),這個字節(jié)就是實(shí)際測量獲得的溫度
;這個轉(zhuǎn)化溫度的方法可是我想出來的哦~~非常簡潔無需乘于0.0625系數(shù)
MOV A,29H
MOV C,40H;將28H中的最低位移入C
RRC A
MOV C,41H
RRC A
MOV C,42H
RRC A
MOV C,43H
RRC A
MOV 29H,A
LCALL DISPLAY;調(diào)用數(shù)碼管顯示子程序
CPL P1.0
AJMP MAIN
; 這是DS18B20復(fù)位初始化子程序
INIT_1820:
SETB P2.2
NOP
CLR P2.2
;主機(jī)發(fā)出延時537微秒的復(fù)位低脈沖
MOV R1,#3
TSR1:MOV R0,#107
DJNZ R0,$
DJNZ R1,TSR1
SETB P2.2;然后拉高數(shù)據(jù)線
NOP
NOP
NOP
MOV R0,#25H
TSR2:
JNB P2.2,TSR3;等待DS18B20回應(yīng)
DJNZ R0,TSR2
LJMP TSR4 ; 延時
TSR3:
SETB FLAG1 ; 置標(biāo)志位,表示DS1820存在
CLR P1.7;檢查到DS18B20就點(diǎn)亮P1.7LED
LJMP TSR5
TSR4:
CLR FLAG1 ; 清標(biāo)志位,表示DS1820不存在
CLR P1.1
LJMP TSR7
TSR5:
MOV R0,#117
TSR6:
DJNZ R0,TSR6 ; 時序要求延時一段時間
TSR7:
SETB P2.2
RET
; 讀出轉(zhuǎn)換后的溫度值
GET_TEMPER:
SETB P2.2
LCALL INIT_1820;先復(fù)位DS18B20
JB FLAG1,TSS2
CLR P1.2
RET ; 判斷DS1820是否存在?若DS18B20不存在則返回
TSS2:
CLR P1.3;DS18B20已經(jīng)被檢測到!!!!!!!!!!!!!!!!!!
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#44H ; 發(fā)出溫度轉(zhuǎn)換命令
LCALL WRITE_1820
;這里通過調(diào)用顯示子程序?qū)崿F(xiàn)延時一段時間,等待AD轉(zhuǎn)換結(jié)束,12位的話750微秒
LCALL DISPLAY
LCALL INIT_1820;準(zhǔn)備讀溫度前先復(fù)位
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#0BEH ; 發(fā)出讀溫度命令
LCALL WRITE_1820
LCALL READ_18200; 將讀出的溫度數(shù)據(jù)保存到35H/36H
CLR P1.4
RET
;寫DS18B20的子程序(有具體的時序要求)
WRITE_1820:
MOV R2,#8;一共8位數(shù)據(jù)
CLR C
WR1:
CLR P2.2
MOV R3,#5
DJNZ R3,$
RRC A
MOV P2.2,C
MOV R3,#21
DJNZ R3,$
SETB P2.2
NOP
DJNZ R2,WR1
SETB P2.2
RET
; 讀DS18B20的程序,從DS18B20中讀出兩個字節(jié)的溫度數(shù)據(jù)
READ_18200:
MOV R4,#2 ; 將溫度高位和低位從DS18B20中讀出
MOV R1,#29H ; 低位存入29H(TEMPER_L),高位存入28H(TEMPER_H)
RE00:
MOV R2,#8;數(shù)據(jù)一共有8位
RE01:
CLR C
SETB P2.2
NOP
NOP
CLR P2.2
NOP
NOP
NOP
SETB P2.2
MOV R3,#8
RE10:
DJNZ R3,RE10
MOV C,P2.2
MOV R3,#21
RE20:
DJNZ R3,RE20
RRC A
DJNZ R2,RE01
MOV @R1,A
DEC R1
DJNZ R4,RE00
RET
;顯示子程序
display: mov a,29H;將29H中的十六進(jìn)制數(shù)轉(zhuǎn)換成10進(jìn)制
mov b,#10 ;10進(jìn)制/10=10進(jìn)制
div ab
mov b_bit,a ;十位在a
mov a_bit,b ;個位在b
mov dptr,#numtab ;指定查表啟始地址
mov r0,#4
dpl1: mov r1,#250 ;顯示1000次
dplop: mov a,a_bit ;取個位數(shù)
MOVC A,@A+DPTR ;查個位數(shù)的7段代碼
mov p0,a ;送出個位的7段代碼
clr p2.7 ;開個位顯示
acall d1ms ;顯示1ms
setb p2.7
mov a,b_bit ;取十位數(shù)
MOVC A,@A+DPTR ;查十位數(shù)的7段代碼
mov p0,a ;送出十位的7段代碼
clr p2.6 ;開十位顯示
acall d1ms ;顯示1ms
setb p2.6
djnz r1,dplop ;100次沒完循環(huán)
djnz r0,dpl1 ;4個100次沒完循環(huán)
ret
;1MS延時
D1MS: MOV R7,#80
DJNZ R7,$
RET
;實(shí)驗(yàn)板上的7段數(shù)碼管0～9數(shù)字的共陰顯示代碼
numtab: DB 0CFH,03H,5DH,5BH,93H,0DAH,0DEH,43H,0DFH,0DBH
end
;溫度傳感器18B20匯編程序,采用器件默認(rèn)的12位轉(zhuǎn)化,最大轉(zhuǎn)化時間750微秒
;將溫度數(shù)據(jù)通過串口發(fā)送出去，波特率2400
;本程序?qū)锳T89C51實(shí)驗(yàn)開發(fā)板編寫.適合12晶振
;本程序經(jīng)過驗(yàn)證,可以顯示溫度+/-和兩位整數(shù)溫度和兩位小數(shù)溫度數(shù)據(jù)
DOT EQU 30H
ZHENGSHU EQU 31H
FLAG1 EQU 38H ;是否檢測到DS18B20的標(biāo)志位
;定義溫度數(shù)據(jù)
DIS_1 EQU 32H ;符號
DIS_2 EQU 33H ;十位
DIS_3 EQU 34H ;個位
DIS_4 EQU 35H ;小數(shù)點(diǎn)后第一位
DIS_5 EQU 36H ;小數(shù)點(diǎn)后第二位
WDDATA BIT P2.2 ;定義DS18B20的數(shù)據(jù)腳為P2.2端口
ORG 0000H
;以下為主程序進(jìn)行CPU中斷方式設(shè)置
CLR EA ;關(guān)閉總中斷
MOV SCON,#50H ;設(shè)置成串口1方式
MOV TMOD,#20H ;波特率發(fā)生器T1工作在模式2上
MOV TH1,#0F3H ;預(yù)置初值(按照波特率2400BPS預(yù)置初值)
MOV TL1,#0F3H ;預(yù)置初值(按照波特率2400BPS預(yù)置初值)
SETB TR1 ;啟動定時器T1
;以上完成串口2400通訊初始化設(shè)置
;-------------------------
; 主程序
;-------------------------
MAIN:
LCALL INIT_1820 ;調(diào)用復(fù)位DS18B20子程序
MAIN1:
LCALL GET_TEMPER;調(diào)用讀溫度子程序
LCALL FORMULA ;通過公式計(jì)算,小數(shù)點(diǎn)后顯示兩位
LCALL BCD
LCALL DISPLAY ;調(diào)用串口顯示子程序
LCALL DELAY500 ;延時0.5秒
LCALL DELAY500 ;延時0.5秒
LCALL DELAY500 ;延時0.5秒
AJMP MAIN1
;-------------------------
; DS18B20復(fù)位初始化程序
;-------------------------
INIT_1820:
SETB WDDATA
NOP
CLR WDDATA
;主機(jī)發(fā)出延時540微秒的復(fù)位低脈沖
MOV R0,#36
LCALL DELAY
SETB WDDATA;然后拉高數(shù)據(jù)線
NOP
NOP
MOV R0,#36
TSR2:
JNB WDDATA,TSR3;等待DS18B20回應(yīng)
DJNZ R0,TSR2
LJMP TSR4 ; 延時
TSR3:
SETB FLAG1 ; 置標(biāo)志位,表示DS1820存在
LJMP TSR5
TSR4:
CLR FLAG1 ; 清標(biāo)志位,表示DS1820不存在
LJMP TSR7
TSR5:
MOV R0,#06BH
TSR6:
DJNZ R0,TSR6 ;復(fù)位成功!時序要求延時一段時間
TSR7:
SETB WDDATA
RET
;-------------------
; 讀出轉(zhuǎn)換后的溫度值
;-------------------
GET_TEMPER:
SETB WDDATA ; 定時入口
LCALL INIT_1820 ;先復(fù)位DS18B20
JB FLAG1,TSS2
RET ; 判斷DS1820是否存在?若DS18B20不存在則返回
TSS2:
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#44H ; 發(fā)出溫度轉(zhuǎn)換命令
LCALL WRITE_1820
MOV R0,#50 ;等待AD轉(zhuǎn)換結(jié)束,12位的話750微秒.
LCALL DELAY
LCALL INIT_1820 ;準(zhǔn)備讀溫度前先復(fù)位
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#0BEH ; 發(fā)出讀溫度命令
LCALL WRITE_1820
LCALL READ_18200; 將讀出的九個字節(jié)數(shù)據(jù)保存到60H-68H
RET
;----------------------------------
;寫DS18B20的子程序(有具體的時序要求)
;----------------------------------
WRITE_1820:
MOV R2,#8 ;一共8位數(shù)據(jù)
CLR C
WR1:
CLR WDDATA
MOV R3,#6
DJNZ R3,$
RRC A
MOV WDDATA,C
MOV R3,#24
DJNZ R3,$
SETB WDDATA
NOP
DJNZ R2,WR1
SETB WDDATA
RET
;--------------------------------------------------
; 讀DS18B20的程序,從DS18B20中讀出九個字節(jié)的數(shù)據(jù)
;--------------------------------------------------
READ_18200:
MOV R4,#9
MOV R1,#60H ; 存入60H開始的九個單元
RE00:
MOV R2,#8
RE01:
CLR C
SETB WDDATA
NOP
NOP
CLR WDDATA
NOP
NOP
NOP
SETB WDDATA
MOV R3,#09
RE10:
DJNZ R3,RE10
MOV C,WDDATA
MOV R3,#23
RE20:
DJNZ R3,RE20
RRC A
DJNZ R2,RE01
MOV @R1,A
INC R1
DJNZ R4,RE00
RET
;------------------------
;溫度計(jì)算子程序
;------------------------
FORMULA: ; 按公式：T實(shí)際=(T整數(shù)-0.25)+( M每度-M剩余)/ M每度
;計(jì)算出實(shí)際溫度，整數(shù)部分和小數(shù)部分分別存于ZHENGSHU單元和DOT單元
;將61H中的低4位移入60H中的高4位，得到溫度的整數(shù)部分，并存于ZHENGSHU單元
MOV 29H,61H
MOV A,60H
MOV C,48H
RRC A
MOV C,49H
RRC A
MOV C,4AH
RRC A
MOV C,4BH
RRC A
MOV ZHENGSHU,A
; ( M每度-M剩余)/ M每度,小數(shù)值存于A中
MOV A,67h
SUBB A,66h
MOV B,#64H
MUL AB
MOV R4,B
MOV R5,A
MOV R7,67H
LCALL DIV457
MOV A,R3
;再減去0.25，實(shí)際應(yīng)用中減去25
SUBB A,#19H
MOV DOT,A ;小數(shù)部分存于DOT中
MOV A,ZHENGSHU
SUBB A,#00H ;整數(shù)部分減去來自小數(shù)部分的借位
MOV ZHENGSHU,A
MOV C,4BH
JNC ZHENG ;是否為負(fù)數(shù)
CPL A
INC A
MOV DIS_1,#2DH ; 零度以下時,第一位顯示"-"號
MOV ZHENGSHU,A
ZHENG:
MOV DIS_1,#2BH ; 零度以上時,第一位顯示"+"號
RET
;------------------------
;雙字節(jié)除以單字節(jié)子程序
;------------------------
DIV457: CLR C
MOV A,R4
SUBB A,R7
JC DV50
SETB OV ;商溢出
RET
DV50: MOV R6,#8 ;求平均值（R4R5／R7－→R3）
DV51: MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV F0,C
CLR C
SUBB A,R7
ANL C,/F0
JC DV52
MOV R4,A
DV52: CPL C
MOV A,R3
RLC A
MOV R3,A
DJNZ R6,DV51
MOV A,R4 ;四舍五入
ADD A,R4
JC DV53
SUBB A,R7
JC DV54
DV53: INC R3
DV54: CLR OV
RET
;---------------------
;轉(zhuǎn)換成非壓縮的BCD碼
;---------------------
BCD: MOV A,ZHENGSHU
MOV B,#0AH
DIV AB
ORL A,#00110000B ;轉(zhuǎn)換成ASCII碼
MOV DIS_2,A
MOV DIS_3,B
MOV A,DIS_3
ORL A,#00110000B ;轉(zhuǎn)換成ASCII碼
mov DIS_3,A
MOV A,DOT
MOV B,#0AH
DIV AB
ORL A,#00110000B ;轉(zhuǎn)換成ASCII碼
MOV DIS_4,A
MOV DIS_5,B
MOV A,DIS_5
ORL A,#00110000B ;轉(zhuǎn)換成ASCII碼
mov DIS_5,A
RET
;----------------------
;串口顯示數(shù)據(jù)子程序
;----------------------
DISPLAY:
CLR TI
MOV A,DIS_1
MOV SBUF,A
JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示+/-
CLR TI
MOV A,DIS_2
MOV SBUF,A
JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示整數(shù)第一位
CLR TI
MOV A,DIS_3
MOV SBUF,A
JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示整數(shù)第二位
CLR TI
MOV A,#2EH
MOV SBUF,A
JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示小數(shù)點(diǎn)
CLR TI
MOV A,DIS_4
MOV SBUF,A
JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示小數(shù)第一位
CLR TI
MOV A,DIS_5
MOV SBUF,A
JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示小數(shù)第一位
CLR TI
MOV A,#0DH;換行
MOV SBUF,A
JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示
CLR TI
MOV A,#0AH;換行
MOV SBUF,A
JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示
RET
;----------------------
;延時子程序
;----------------------
;為保證DS18B20的嚴(yán)格I/O時序，需要做較精確的延時
;在DS18B20操作中，用到的延時有15 μs，90 μs，270 μs，540 μs
;因這些延時均為15 μs的整數(shù)倍，因此可編寫一個DELAY15（n）函數(shù)
DELAY: ;11.05962M晶振
LOOP: MOV R1,#06H
LOOP1: DJNZ R1,LOOP1
DJNZ R0,LOOP
RET
;500毫秒延時子程序，占用R4、R5
DELAY500:MOV R4,#248
DA222:MOV R5,#248
DJNZ R5,$
DJNZ R4,DA222
RET
END
DS18B20集成電路芯片不包含在AT89C51試驗(yàn)開發(fā)板中！
DS18B20芯片8元一個
DS18B20測溫電纜帶接插件10元一套，可以配合實(shí)驗(yàn)開發(fā)板使用
備注：如果不需要AT89C51實(shí)驗(yàn)開發(fā)板中的12伏電源變壓器，價(jià)格可以降低10元
銀行帳號及郵購需知 立即進(jìn)入訂貨系統(tǒng)! 查看全部郵購清單
郵局匯款地址：郵編226200 江蘇省啟東市江海中路511號水晶苑 A1 謝剛 收
電話/傳真：0513－83342087 小靈通：0513－83082087 聯(lián)系人：謝剛
電子信箱：